Routines
Prev: 06369 Up: Map Next: 06437
06415: THE 'LN-FETCH' SUBROUTINE
Used by the routines at ED_DOWN and LIST.
This subroutine is entered with the HL register pair addressing a system variable - S-TOP or E-PPC.
The subroutine returns with the system variable holding the line number of the following line.
Input
HL S-TOP or E-PPC
LN_FETCH 06415 LD E,(HL) The line number held by the system variable is collected.
06416 INC HL
06417 LD D,(HL)
06418 PUSH HL The pointer is saved.
06419 EX DE,HL The line number is moved to the HL register pair and incremented.
06420 INC HL
06421 CALL LINE_ADDR The address of the start of this line is found, or the next line if the actual line number is not being used.
06424 CALL LINE_NO The number of that line is fetched.
06427 POP HL The pointer to the system variable is restored.
This entry point is used by the routine at ED_UP.
LN_STORE 06428 BIT 5,(IY+55) Return if in 'INPUT mode' (bit 5 of FLAGX set).
06432 RET NZ
06433 LD (HL),D Otherwise proceed to enter the line number into the two locations of the system variable.
06434 DEC HL
06435 LD (HL),E
06436 RET Return when it has been done.
Prev: 06369 Up: Map Next: 06437